Launching WinWedge from within Excel

#If VBA7 Then
    Declare PtrSafe Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hwnd As LongPtr, _
    ByVal lpOperation As String, ByVal lpFile As String, ByVal lpParameters As String, _
    ByVal lpDirectory As String, ByVal nShowCmd As Long) As LongPtr
#Else
    Declare Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hwnd As Long, _
    ByVal lpOperation As String, ByVal lpFile As String, ByVal lpParameters As String, _
    ByVal lpDirectory As String, ByVal nShowCmd As Long) As Long
#End If

Sub Auto_Open()

   OpenFile "device.SW3" ' or C:\FullPath\device.SW3

End Sub

Sub OpenFile(ByVal File As String)

Dim FullPath As String

#If VBA7 Then
    Dim x As LongPtr
#Else
     Dim x As Long
#End If
   'Determine the full path of the file
   If InStr(File, "\") = 0 Then
      FullPath = ThisWorkbook.Path & "\" & File
   Else
      FullPath = File
   End If

   'Launch the configuration file
   x = ShellExecute(0, "open", FullPath, vbNullString, vbNullString, 0)

   'Prompt the user if launch fails
   If x < 33 Then
      MsgBox "The file: " & FullPath & " did not launch successfully"
   End If

End Sub

Sub Auto_Open()

   OpenFileAlt "device.SW3", "C:\FullPath\WinWedge.exe"

End Sub

Sub OpenFileAlt(ByVal File As String, ByVal WinWedge As String)

   Dim FullPath As String, x As Long

   'Determine the full path of the file
   If InStr(File, "\") = 0 Then
      FullPath = ThisWorkbook.Path & "\" & File
   Else
      FullPath = File
   End If

   'Launch the configuration file
    x = Shell(WinWedge + " " + FullPath, vbNormalFocus)

   'Prompt the user if launch fails
   If x < 33 Then
      MsgBox "The file: " & FullPath & " did not launch successfully"
   End If

End Sub

' This code automatically runs when Excel is closed
Sub Auto_Close()

   'Ignore Errors
   On Error Resume Next

   ' Open a DDE link with WinWedge
   chan = DDEInitiate("WinWedge", "COM1")

   ' Tell WinWedge to Quit
   DDEExecute chan, "[Appexit]"

   ' Terminate the DDE link
   DDETerminate chan

End Sub